bananatools/meson.build

project(
    'bananatools',
    'c',
    version: '0.1.0',
    default_options: [
        'werror=true',
    ],
)

add_project_arguments(
    '-DCOBJMACROS',
    '-DDIRECTINPUT_VERSION=0x0800',
    '-DWIN32_LEAN_AND_MEAN',
    '-D_WIN32_WINNT=_WIN32_WINNT_WIN7',
    '-DMINGW_HAS_SECURE_API=1',
    '-Wno-unused',
    language: 'c',
)

if meson.get_compiler('c').get_id() != 'msvc'
    add_project_arguments(
        '-ffunction-sections',
        '-fdata-sections',
        language: 'c',
    )

    add_project_link_arguments(
        '-Wl,--enable-stdcall-fixup',
        '-Wl,--exclude-all-symbols',
        '-Wl,--gc-sections',
        '-static-libgcc',
        language: 'c',
    )
endif

cc = meson.get_compiler('c')
shlwapi_lib = cc.find_library('shlwapi')
dinput8_lib = cc.find_library('dinput8')
dxguid_lib = cc.find_library('dxguid')
xinput_lib = cc.find_library('xinput')
cfgmgr32_lib = cc.find_library('cfgmgr32')

inc = include_directories('.')
capnhook = subproject('capnhook')

subdir('iccard')
subdir('hooklib')
subdir('util')
subdir('aimeio')
subdir('gfxhook')
subdir('jvs')
subdir('board')
subdir('platform')
subdir('amcus')


subdir('ferrumio')
subdir('taikoio')
subdir('exvs2io')
subdir('saoio')
subdir('mkacio')
subdir('tekkenio')

subdir('taikohook')
subdir('ferrumhook')
subdir('exvs2hook')
subdir('saohook')
subdir('mkachook')
subdir('tekkenhook')